1. <%   
2. '**********************************************   
3. 'vbs Cache類  
4. ' 屬性valid，是否可用，取值前判斷   
5. ' 屬性name，cache名，新建對象后賦值   
6. ' 方法add(值,到期時間)，設置cache內容   
7. ' 屬性value，返回cache內容   
8. ' 屬性blempty，是否未設置值   
9. ' 方法makeEmpty，釋放內存，測試用   
10. ' 方法equal(變量1)，判斷cache值是否和變量1相同   
11. ' 方法expires(time)，修改過期時間為time   
12. ' 木鳥寫的緩存類  
13. '**********************************************   
14.  
15. class Cache   
16. private obj 'cache內容   
17. private expireTime '過期時間   
18. private expireTimeName '過期時間application名   
19. private cacheName 'cache內容application名   
20. private path 'uri   
21.  
22. private sub class_initialize()   
23.     path=request.servervariables("url")   
24.     path=left(path,instrRev(path,"/"))   
25. end sub   
26.  
27. private sub class_terminate()   
28. end sub   
29.  
30. public property get blEmpty   
31.     '是否為空   
32.     if isempty(obj) then   
33.         blEmpty=true   
34.     else   
35.         blEmpty=false   
36.     end if   
37. end property   
38.  
39. public property get valid   
40.     '是否可用(過期)   
41.     if isempty(obj) or not isDate(expireTime) then   
42.         valid=false   
43.     elseif CDate(expireTime)<now then   
44.         valid=false   
45.     else   
46.         valid=true   
47.     end if   
48. end property   
49.  
50. public property let name(str)   
51.     '設置cache名   
52.     cacheName=str & path   
53.     obj=application(cacheName)   
54.     expireTimeName=str & "expires" & path   
55.     expireTime=application(expireTimeName)   
56. end property   
57.  
58. public property let expires(tm)   
59.     '重設置過期時間   
60.     expireTime=tm   
61.     application.lock   
62.     application(expireTimeName)=expireTime   
63.     application.unlock   
64. end property   
65.  
66. public sub add(var,expire)   
67.     '賦值   
68.     if isempty(var) or not isDate(expire) then   
69.         exit sub   
70.     end if   
71.     obj=var   
72.     expireTime=expire   
73.     application.lock   
74.     application(cacheName)=obj   
75.     application(expireTimeName)=expireTime   
76.     application.unlock   
77. end sub   
78.  
79. public property get value   
80.     '取值   
81.     if isempty(obj) or not isDate(expireTime) then   
82.         value=null   
83.     elseif CDate(expireTime)<now then   
84.         value=null   
85.     else   
86.         value=obj   
87.     end if   
88. end property   
89.  
90. public sub makeEmpty()   
91.     '釋放application   
92.     application.lock   
93.     application(cacheName)=empty   
94.     application(expireTimeName)=empty   
95.     application.unlock   
96.     obj=empty   
97.     expireTime=empty   
98. end sub   
99.  
100. public function equal(var2)   
101.     '比較   
102.     if typename(obj)<>typename(var2) then   
103.         equal=false   
104.     elseif typename(obj)="Object" then   
105.         if obj is var2 then   
106.             equal=true   
107.         else   
108.             equal=false   
109.         end if   
110.     elseif typename(obj)="Variant()" then   
111.         if join(obj,"^")=join(var2,"^") then   
112.             equal=true   
113.         else   
114.             equal=false   
115.         end if   
116.     else  
117.         if obj=var2 then   
118.             equal=true   
119.         else   
120.             equal=false   
121.         end if   
122.     end if   
123. end function   
124.  
125. end class   
126.  
127. dim content,myCache  
128. Set myCache = new Cache  
129. myCache.name="sofoisndoffo" '定義緩存名稱   
130. if myCache.valid then '如果緩存有效  
131.  content=myCache.value '讀取緩存內容  
132. else  
133.  content="sosuo8.com測試" '大量內容，可以是非常耗時大量數據庫查詢記錄集  
134.  myCache.add content,dateadd("n",1000,now) '將內容賦值給緩存，并設置緩存有效期是當前時間＋1000分鐘  
135. end if  
136. Response.Write(content)  
137. 'myCache.makeEmpty()    
138. set clsCache=nothing '釋放對象  
139. %>