国内精品伊人久久,亚洲大片免费观看,国产拍在线

第一次寫ASP類,實現功能:分段統計程序執行時間,輸出統計表等.

復制代碼代碼如下:

Class ccClsProcessTimeRecorder
'程序作者:明月星光
'作者主頁:http://www.5iya.com/blog
'http://www.kuozhanming.com
'ASP程序代碼執行時間統計類

  Private ccInti,ccIntNonceTime,ccIntDecimal
  Private ccIntStartTime,ccIntEndTime,ccIntNow,ccIntNonce
  Private ccStrInterval,ccStrEvent,ccStrTime,ccStrStatisticLog,ccStrFormatInterval
  Private ccArrEvent,ccArrTime

  Private Sub Class_Initialize
    ccStrInterval = "|"  '默認分隔符
    ccIntDecimal = 4    '小數點后位數
    ccStrEvent = ""
    ccStrTime = ""
    ccStrFormatInterval = "<br />" & vbCrLf
    ccIntStartTime = Timer
    ccIntNow = ccIntStartTime
    ccIntNonce = ccIntStartTime
  End Sub

  Public Sub Record(ccStrEventName)
    ccStrEvent = ccStrEvent & ccStrInterval & Replace(ccStrEventName,ccStrInterval,"")
    ccStrTime = ccStrTime & ccStrInterval & FormatNumber(Timer-ccIntNow,ccIntDecimal,True,False,True)
    ccIntNow = Timer
  End Sub

  Public Property Let Format(ccStrFormatType)
    If LCase(Trim(ccStrFormatType)) = "html" Then
      ccStrFormatInterval = "<br />" & vbCrLf
    Else
      ccStrFormatInterval = vbCrLf
    End If
  End Property

  Public Function Statistic
    If InStr(ccStrEvent,ccStrInterval) > 0 Then
      ccIntEndTime = Timer
      ccArrEvent = Split(ccStrEvent,ccStrInterval)
      ccArrTime = Split(ccStrTime,ccStrInterval)
      ccStrStatisticLog = ccStrStatisticLog & "Process Time Record" & ccStrFormatInterval
      ccStrStatisticLog = ccStrStatisticLog & "--------------------------------------" & ccStrFormatInterval
      For ccInti = 1 To UBound(ccArrEvent)
        ccStrStatisticLog = ccStrStatisticLog & ccArrEvent(ccInti) & " : " & ccArrTime(ccInti) & " s" & ccStrFormatInterval
      Next
      ccStrStatisticLog = ccStrStatisticLog & "--------------------------------------" & ccStrFormatInterval
      ccStrStatisticLog = ccStrStatisticLog & "Total : " & FormatNumber(ccIntEndTime-ccIntStartTime,ccIntDecimal,True,False,True) & " s"
      Statistic = ccStrStatisticLog
    Else
      Statistic = "No Record"
    End If
  End Function

  Public Function Nonce
    ccIntNonceTime = FormatNumber(Timer-ccIntNonce,ccIntDecimal,True,False,True)
    ccIntNonce = Timer
    Nonce = ccIntNonceTime
  End Function

  Public Function Total
    Total = FormatNumber(Timer-ccIntStartTime,ccIntDecimal,True,False,True)
  End Function

End Class

類屬性:
1.Format
輸出時是否帶HTML換行標簽
-html:輸出HTML換行標簽和文本換行符(默認)
-text:僅輸出文本換行符

類方法:
1.Record("Code Name")
統計自上一次調用Record方法至現在的時間(第一次調用時統計聲明類時至調用時時間),最后在Statistic中輸出

類函數:(即時返回信息)
1.Nonce
輸出自上一次調用nonce函數至現在的時間(第一次調用時統計聲明類時至調用時時間)
2.Total
輸出聲明類到現在總時間
3.Statistic
輸出所有Record統計信息和總程序時間

實例代碼:

復制代碼代碼如下:

Dim objRecord,i,k,j,x

Set objRecord = New ccClsProcessTimeRecorder
objRecord.Format = "html"

For i = 1 To 100000
  x = 2 + 2
Next

Call objRecord.Record("加法")
For j = 1 To 100000
  x = 2 * 2
Next

Call objRecord.Record("乘法")

For k = 1 To 100000
  x = 2 ^ 2
Next

Call objRecord.Record("開方")

Response.Write objRecord.Statistic

輸出:
Process Time Record
--------------------------------------
加法 : 0.0625 s
乘法 : 0.0469 s
開方 : 0.1094 s
--------------------------------------
Total : 0.2188 s